1. Buatlah sebuah flash document.

2. Buatlah sebuah objek seperti gambar dibawah ini :

3. Seleksi objek tersebut dan tekan F8. Pada panel yang muncul masukkan play_btn sebagai name dan button sebagai type lalu tekan ok.

4. Seleksi play_btn di stage dan tekan Ctrl+F3. Pada panel properties yang muncul masukkan play_btn sebagai instance name.

5. Buatlah sebuah objek seperti gambar dibawah ini :

6. Seleksi objek tersebut dan tekan F8. Pada panel yang muncul masukkan stop_btn sebagai name dan button sebagai type lalu tekan ok.

7. Seleksi stop_btn di stage dan pada panel properties masukkan stop_btn sebagai instance name.

8. Atur letaknya sesuai keinginan anda.

9. Tekan Ctrl+R, pada panel yang muncul cari suara yang diinginkan kemudian tekan open.

10. Tekan Ctrl+L, pada panel library yang muncul klik kanan suara yang baru di import kemudian pilih Linkage. Pada panel yang muncul berikan tanda contreng pada Export for ActionScript dan masukkan musik di dalam kotak identifier lalu tekan ok.

11. Klik frame 1 dan tekan F9. Pada panel actions yang muncul masukkan script berikut :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52

//membuat variable bernama kurang dengan nilai false
kurang = false;
//membuat variable bernama vol dengan nilai 0
vol = 100;
//membuat fungsi bernama mainkanMusik
function mainkanMusik() {
	//menghentikan suara yang dimainkan agar suara yang dimainkan tidak double
	musik.stop();
	//mengubah nilai variable vol menjadi 0
	vol = 100;
	//mengubah nilai variable kurang menjadi false
	kurang = false;
	//membuat volume musik yang dimainkan menjadi maksimal
	musik.setVolume(100);
	//membuat variable musik sebagai sound object
	musik = new Sound();
	//masukkan suara berlinkage bgm dari panel library ke dalam variable musik
	musik.attachSound("bgm");
	//mainkan suara di dalam variable musik sebanyak 999 kali
	musik.start(0,999);
}
//perintah yang dijalankan ketika frame dimainkan
onEnterFrame = function () {
	//jika variable kurang bernilai true
	if (kurang) {
		//nilai variable vol dikurangi 3
		vol -= 3;
		//atur volume suara yang dimainkan sesuai nilai variable vol
		musik.setVolume(vol);
		//jika variable vol bernilai kurang dari atau sama dengan 0
		if (vol<=0) {
			//hentikan suara yang dimainkan 
			musik.stop();
			//ubah nilai variable kurang menjadi false
			kurang = false;
			//ubah nilai variable vol menjadi 100
			vol = 100;
		}
	}
};
//jika tombol play_btn ditekan
play_btn.onPress = function() {
	//jalankan function mainkanMusik()
	mainkanMusik();
};
//jika tombol stop_btn ditekan
stop_btn.onPress = function() {
	//ubah nilai variable kurang menjadi true
	kurang = true;
};
//menjalankan fungsi mainkanMusik ketika swf pertama kali dijalankan
mainkanMusik();

12. Tekan Ctrl+Enter untuk melihat hasilnya.

13. Silahkan anda menekan tombol stop. Volume suara akan berhenti sedikit demi sedikit sebelum akhirnya berhenti.

14. Tutorial di atas hanya digunakan jika suara yang digunakan hanya 1 buah. Jika anda menggunakan suara lebih dari 1 dan ingin agar suaranya hanya berhenti salah satu saja, silahkan baca terlebih dahulu tutorial Mengatur Volume Pada Beberapa Sound kemudian gabungkan dengan tutorial ini.

15. Jika anda hanya menggunakan tutorial ini tanpa menggabungkannya dengan tutorial Mengatur Volume Pada Beberapa Sound, ketika anda menekan tombol stop seluruh suara akan berkurang volumenya kemudian berhenti.

Sourcenya dapat di download di sini

Berikut contoh penggunaannya.
1. Buatlah sebuah flash document.

2. Buatlah sebuah static text bertuliskan Masuk.

3. Buatlah sebuah persegi berwarna merah dengan garis hitam dan buat panjang serta lebarnya menutupi static text bertuliskan Masuk.

4. Seleksi persegi dan static text kemudian tekan F8. Pada panel yang muncul masukkan masuk_btn sebagai name dan button sebagai movie clip lalu tekan ok.

5. Seleksi masuk_btn kemudian tekan Ctrl+F3. Pada panel properties yang muncul masukkan masuk_btn sebagai instance name.

6. Letkkan masuk_btn di tengah-tengah stage.

7. Klik kanan frame 2 dan pilih Insert Blank Keyframe.

8. Klik frame 2 agar anda aktif di frame tersebut kemudian buatlah sebuah Input Text di stage.

9. Seleksi Input Text tersebut dan pada panel properties masukan txt sebagai Var, 20 sebagai Maximum characters, serta aktifkan Show border around text dan Align Center.

10. Letkkan input text di tengah-tengah stage.

11. Klik frame 1 dan tekan F9. Pada panel actions yang muncul masukkan script berikut :

1
2
3
4
5
6
7

//menghentikan frame agar tidak memainkan frame selanjutnya
stop();
//ketika tombol masuk_btn ditekan
masuk_btn.onPress = function() {
	//mainkan frame 2
	gotoAndPlay(2);
};

12. Klik frame 2 dan pada panel actions masukkan script berikut :

1
2
3
4

//menghentikan frame agar tidak memainkan frame selanjutnya
stop();
//membuat fokus pada input text dengan var txt
Selection.setFocus("txt");

13. Tekan Ctrl+Enter untuk melihat hasilnya :

14. Tekan tombol Masuk lalu anda akan berada di stage yang terdapat input text. Silahkan langsung ketikkan apa saja tanpa anda perlu menekan input textnya terlebih dahulu.

15. Input text menjadi tidak aktif jika anda menekan objek selain input text. Untuk masalah ini, anda dapat mengakalinya dengan membuat persegi (panjang dan lebar sesuai ukuran stage) dan masukan bg sebagai instance namenya. Kemudian tambahkan script berikut pada panel actions di frame tempat movie clip ini berada:

1
2
3
4
5
6
7

//hilangkan kursor tangan pada movie clip bg
bg.useHandCursor = false;
//ketika movie clip bg ditekan
bg.onPress = function() {
	//membuat fokus pada input text dengan var txt
	Selection.setFocus("txt");
};

Sourcenya dapat di download di sini

Untuk menghentikan suara kita cukup menuliskan stop() pada variable yang menampung suara yang sedang dimainkan. Misalnya : suara ditampung pada variable Musicz, maka untuk menghentikannya kita menuliskan Musicz.stop()

Untuk contoh lainnya, kita akan menggabungkannya dengan tutorial Pause dan Play Suara :
1. Bukalah fla dari source Pause dan Play Suara.

2. Buatlah sebuah objek seperti gambar dibawah ini :

3. Seleksi objek tersebut dan tekan F8. Pada panel yang muncul masukan stop_btn sebagai name dan button sebagai type lalu tekan ok.

4. Letakan seluruh objek di stage menjadi seperti ini :

5. Klik frame 1 dan tekan F9. Pada panel actions yang muncul ubah seluruh scriptnya menjadi seperti ini :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55

//membuat variable bernama Pause dengan nilai false
Pause = false;
//membuat variable bernama Stop dengan nilai false
Stop = false;
//membuat fungsi bernama mainkanMusik
function mainkanMusik() {
	//membuat variable musik sebagai sound object
	musik = new Sound();
	//masukkan suara berlinkage bgm dari panel library ke dalam variable musik
	musik.attachSound("bgm");
	//mainkan suara di dalam variable musik sebanyak 999 kali
	musik.start(0,999);
}
//jika tombol pause_btn ditekan
pause_btn.onPress = function() {
	//membuat variable posisi dengan nilai pembualatan ke bawah dari posisi terakhir suara pada variable musik yang dibagi 1000
	posisi = Math.floor(musik.position/1000);
	//hentikan suara pada variable musik
	musik.stop();
	//ubah nilai variable Pause menjadi true
	Pause = true;
};
//jika tombol play_btn ditekan
play_btn.onPress = function() {
	//jika variable Stop bernilai true
	if (Stop) {
		//mainkan suara di dalam variable musik sebanyak 999 kali
		musik.start(0,1);
		//ubah nilai variable Pause menjadi false
		Pause = false;
		//ubah nilai variable Stop menjadi true false
		Stop = false;
	}
	//jika variable Pause bernilai true dan variable Stop bernilai false
	if (Pause && !Stop) {
		//mainkan suara di dalam variable musik sesuai nilai variable posisi sebanyak 1 kali
		musik.start(posisi,1);
		//ubah nilai variable Pause menjadi false
		Pause = false;
	}
	//jika suara di dalam variable musik selesai dimainkan
	musik.onSoundComplete = function() {
		//jalankan fungsi mainkanMusik
		mainkanMusik();
	};
};
//jika tombol stop_btn ditekan
stop_btn.onPress = function() {
	//ubah nilai variable Stop menjadi true
	Stop = true;
	//hentikan suara pada variable musik
	musik.stop();
};
//menjalankan fungsi mainkanMusik ketika swf pertama kali dijalankan
mainkanMusik();

6. Tekan Ctrl+Enter untuk melihat hasilnya.

7. Selain menggunakan stop(), kita juga bisa menggunakan stopAllSounds() untuk menghentikan suara. Bedanya, stop() hanya menghentikan 1 suara sedangkan stopAllSounds() akan menghentikan seluruh suara yang ada. Silahkan anda pilih sesuai kebutuhan.

Sourcenya dapat di download di sini

1. Buatlah sebuah flash document.

2. Buatlah sebuah persegi dengan menggunakan rectangle tool.

3. Buat panjang dan lebar persegi sama dengan panjang dan lebar stage.

4. Letakkan persegi tersebut ditengah-tengah stage.

5. Klik frame 1 dan tekan F9. Pada panel actions yang muncul masukkan script berikut :

1
2
3
4
5
6
7
8
9
10
11
12
13
14

//perintah yang dijalankan ketika frame dimainkan
onEnterFrame = function () {
	//jika visible bernilai true
	if (_visible) {
		//ubah nilai visible menjadi false
		//seluruh objek menjadi tidak terlihat
		_visible = false;
	//jika visible bernilai false
	} else {
		//ubah nilai visible menjadi true
		//seluruh objek menjadi terlihat
		_visible = true;
	}
};

6. Tekan Ctrl+Enter untuk melihat hasilnya.

7. Jangan terlalu lama meihatnya, karena akan membuat mata anda sakit.

8. Gambar persegi di dalam tutorial ini hanya sebagai contoh saja. Bila di stage sudah ada objeknya maka gambar persegi tidak perlu dibuat.

9. Untuk contoh penggunaannya, anda dapat memasukkan script di atas ke dalam sebuah function. Lalu panggil function tersebut ketika presentasi atau pembelajaran interaktif yang anda buat berpindah halaman.

Sourcenya dapat di download di sini

1. Buatlah flash document.

2. Buatlah sebuah gambar seperti di bawah ini. Anda dapat menggunakan oval tool, text tool, dan panel transform untuk membuatnya.

3. Untuk garisnya kami akan membuat ukurannya seperti ini : garis jam lebih panjang dari garis menit, garis menit lebih panjang dari garis detik, garis detik lebih panjang dari garis jam Anda dapat mengubah ukurannya sesuai keinginan anda.

4. Buatlah tiga buah garis seperti gambar di bawah ini :

5. Seleksi garis yang paling kecil, kemudian tekan F8. Pada panel yang muncul masukkan jam_mc dan movie clip sebagai type serta pastikan titik registrationnya berada di tengah bagian bawah lalu tekan ok.

6. Seleksi movie clip jam_mc di stage kemudian tekan Ctrl+F3. Pada panel properties yang muncul masukkan jam_mc sebagai instance name.

7. Seleksi garis kedua (garis yang tidak terlalu panjang), kemudian tekan F8. Pada panel yang muncul masukkan detik_mc dan movie clip sebagai type serta pastikan titik registrationnya berada di tengah bagian bawah lalu tekan ok.

8. Seleksi movie clip detik_mc di stage kemudian tekan Ctrl+F3. Pada panel properties yang muncul masukkan detik_mc sebagai instance name.

9. Seleksi garis ketiga (garis yang paling panjang), kemudian tekan F8. Pada panel yang muncul masukkan menit_mc dan movie clip sebagai type serta pastikan titik registrationnya berada di tengah bagian bawah lalu tekan ok.

8. Seleksi movie clip menit_mc di stage kemudian tekan Ctrl+F3. Pada panel properties yang muncul masukkan menit_mc sebagai instance name.

9. Letakan movie clip jam_mc di tengah lingkaran yang kita buat sebelumnya.

10. Selanjutnya letakan movie clip menit_mc di tengah lingkaran (ditempat yang sama movie clip jam_mc berada).

11. Lalu letakan juga movie clip detik_mc di tengah lingkaran (ditempat yang sama movie clip jam_mc dan menit_mc berada).

12. Setelah semuanya terpasang, klik frame 1 dan tekan F9. Pada panel actions yang muncul masukkan script berikut :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22

//perintah yang dijalankan ketika frame dimainkan
onEnterFrame = function () {
	//membuat variable waktu sebagai date object
	waktu = new Date();
	//membuat variable jam dengan nilai sama dengan jam pada komputer
	jam = waktu.getHours();
	//membuat variable menit dengan nilai sama dengan menit pada komputer
	menit = waktu.getMinutes();
	//membuat variable detik dengan nilai sama dengan detik pada komputer
	detik = waktu.getSeconds();
	//digunakan jika komputer menggunakan sistem 12 jam
	//jika nilai variable jam lebih dari 12 maka akan dikurangi 12
	if (jam>12) {
		jam -= 12;
	}
	//movie clip jam_mc akan berotasi sesuai nilai variable jam dikali 30 yang ditambah nilai variable menit di bagi 2
	jam_mc._rotation = jam*30+(menit/2);
	//movie clip jam_mc akan berotasi sesuai nilai variable menit dikali 6
	menit_mc._rotation = menit*6;
	//movie clip detik_mc akan berotasi sesuai nilai variable detik dikali 6
	detik_mc._rotation = detik*6;
};

13. Tekan Ctrl+Enter untuk melihat hasilnya.

Sourcenya dapat di download di sini

Berikut ini contoh script yang biasa digunakan untuk mengatur seluruh sound :

1
2
3
4

musik = new Sound();
musik.attachSound("musik");
musik.setVolume(50);
musik.start(0, 1);

Sedangkan di bawah ini contoh script untuk mengatur sound secara satu per satu :

1
2
3
4
5

msk_mc = this.createEmptyMovieClip("msk_mc", this.getNextHighestDepth());
musik = new Sound(msk_mc);
musik.attachSound("musik");
musik.setVolume(50);
musik.start(0, 1);

Untuk contoh penggunaanya silahkan lihat di bawah ini :
1. Buatlah sebuah flash document.

2. Pilih menu bar File>Import>Import to Library. Pada panel yang muncul silahkan cari 2 buah suara yang akan digunakan. Kalau bisa suaranya berupa musik. Setelah itu silahkan seleksi kedua buah suara tersebut dan tekan open.

3. Tekan Ctrl+L, pada panel library yang muncul anda akan melihat dua buah suara yang baru saja anda import tadi.

4. Klik kanan suara pertama pada panel library kemudian pilih Linkage. Pada panel yang muncul berikan tanda contreng pada Export for ActionScript lalu masukkan musik1 di dalam kotak identifier lalu tekan ok.

5. Klik kanan suara kedua pada panel library kemudian pilih Linkage. Pada panel yang muncul berikan tanda contreng pada Export for ActionScript lalu masukkan musik2 di dalam kotak identifier lalu tekan ok.

6. Klik frame 1 dan tekan F9. Pada panel actions yang muncul masukkan script berikut :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23

//-----||-----//
//membuat movie clip kosong bernama msk1_mc pada kedalam paling atas
msk1_mc = this.createEmptyMovieClip("msk1_mc", this.getNextHighestDepth());
//membuat variable bernama musik1 menjadi sound object sekaligus memasukkan movie clip msk1_mc ke dalam musik1 tersebut
musik1 = new Sound(msk1_mc);
//memasukkan suara dari library dengan identifier musik1 ke dalam sound object musik1
musik1.attachSound("musik1");
//mengatur volume  suara pada sound object musik1 menjadi 100
musik1.setVolume(100);
//mainkan suara yang ada pada sound object musik1 sebanyak 999 kali
musik1.start(0, 999);
//-----||-----//
//membuat movie clip kosong bernama msk2_mc pada kedalam paling atas
msk2_mc = this.createEmptyMovieClip("msk2_mc", this.getNextHighestDepth());
//membuat variable bernama musik2 menjadi sound object sekaligus memasukkan movie clip msk2_mc ke dalam musik2 tersebut
musik2 = new Sound(msk2_mc);
//memasukkan suara dari library dengan identifier musik2 ke dalam sound object musik2
musik2.attachSound("musik2");
//mengatur volume  suara pada sound object musik2 menjadi 50
musik2.setVolume(50);
//mainkan suara yang ada pada sound object musik2 sebanyak 999 kali
musik2.start(0, 999);
//-----||-----//

7. Tekan Ctrl+Enter untuk melihat hasilnya.

Sourcenya dapat di download di sini

1. Buatlah sebuah flash document.

2. Buatlah sebuah static text bertuliskan B. Seleksi static text ini kemudian tekan F8. Pada panel yang muncul masukkan b_mc sebagai name dan movie clip sebagai type serta pastikan titik registrationnya berada di tengah-tengah lalu tekan ok.

3. Seleksi b_mc di stage dan tekan Ctrl+F3. Pada panel properties yang muncul masukkan b_mc di dakam kotak instance name.

4. Klik frame 1 dan tekan F9. Pada panel actions yang muncul masukkan script berikut :

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37

//membuat variable balik dengan nilai false di dalam movie clip b_mc
b_mc.balik = false;
//membuat variable waktu dengan nilai 0 di dalam movie clip b_mc
b_mc.waktu = 0;
//ketika kursor mouse berada di atas movie clip b_mc 
b_mc.onRollOver = function() {
	//ubah nilai variable balik di dalam movie b_mc menjadi false
	this.balik = true;
};
//perintah yang dijalankan ketika frame pada movie clip b_mc dimainkan
b_mc.onEnterFrame = function() {
	//jika nilai variable balik di dalam movie clip b_mc bernilai true
	if (this.balik) {
		//jika skala x movie clip b_mc lebih dari -100
		if (this._xscale>-100) {
			//skala x movie clip b_mc dikurangi 20
			this._xscale -= 20;
		}
		//jika skala x movie clip b_mc kurang dari sama dengan -100 
		if (this._xscale<=-100) {
			//variable waktu di dalam movie clip b_mc ditambah 1
			this.waktu++;
			//jika variable waktu di dalam movie clip b_mc bernilai 20
			if (this.waktu == 20) {
				//ubah nilai variable balik di dalam movie clip b_mc menjadi false
				this.balik = false;
				//ubah nilai variable waktu di dalam movie clip b_mc menjadi 0
				this.waktu = 0;
			}
		}
	}
	//jika skala x movie clip b_mc kurang dari 100  
	if (!this.balik && this._xscale<100) {
		//skala x movie clip b_mc ditambah 20
		this._xscale += 20;
	}
};

5. Tekan Ctrl+Enter untuk melihat hasilnya.

6. Berikut contoh lain dari membalik text.

7. Cara membuatnya sama. Anda perlu menjadikan masing-masing static text menjadi movie clip.

8. Untuk script dan pemberian instance name masing-masing movie clip, dapat anda lihat langsung pada fla yang berada di dalam source tutorial ini.

Sourcenya dapat di download di sini